如何将公式改为选股公式的简易方法

飞狐.分析家.大智慧1.大智慧L2.通达信

步骤一.将所有的显示式":",改为不显示式":="
选股条件的基本要求,为只能输出1个条件式,故需先将公式中所有的显示式":"改为不显示式":=",
如果原来显示式后面接有线型描述(颜色.对齐..等),亦请一并删除(有些软件不支援 如:分析家)

例如:
ma1:ma(c,5),colorred;
ma2:ma(c,10),colorgreen,POINTDOT;
.....

先改为
ma1:=ma(c,5);
ma2:=ma(c,10);
.....


步骤二.找出选股条件,并写成选股式引用:
条件的寻找方法,依不同目的,大致可分以下几种:

1.'字'选股     如:'买'选股
方法:先找出公式中出现有'字'的地方,该式开头会以DRAW..TEXT开头,
DRAWTEXT  DRAWTEXTEX  DRAWYITEXT DRAWFLAGTEXT DRAWMOVETEXT
找到后,该函数(条件, ,'字')后面括号内的第1个即为条件,将该条件复制出来并加上分号即可

例如:
{求'5日均>10日均'选股}
ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWTEXT(ma1>ma2,ma1,'5日均>10日均');
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
ma1>ma2;

2.图标选股     如:笑脸选股
方法:
先依不同软件,找出该图标的代号,
再找出公式中出现DRAWICON函数(条件,   ,图标代号)的式子,对照图标的代号(括号内的第3个),如果该图标代号为所求代号,
该函数后面括号内的第1个即为条件,将该条件复制出来并加上分号即可

例如:
{求图标1选股}
ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWicon(ma1>ma2,ma1,1);
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
ma1>ma2;

3.A线上穿(下穿)B线选股  {上穿--金叉,下穿--死叉}
方法:A线上穿B线:  cross(A,B);
     A线下穿B线:  cross(B,A);

例如:
{求ma1上穿ma2选股}
ma1:ma(c,5);
ma2:ma(c,10);
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma1,ma2);

{求ma1下穿ma2选股}
ma1:ma(c,5);
ma2:ma(c,10);
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma2,ma1);


4.线A上拐(下拐) 选股  
方法:线A上拐:  cross(A,ma(A,2));    或  cross(A,ref(A,1));{aduo提供}
     线A下拐:  cross(ma(A,2),A);    或  cross(ref(A,1),A);{aduo提供}

例如:
{求改成ma1上拐}
ma1:ma(c,5);
[解]
ma1:=ma(c,5);
cross(ma1,ma(ma1,2));
或
ma1:=ma(c,5);
cross(ma1,ref(ma1,1));

{求改成ma1下拐}
ma1:ma(c,5);
[解]
ma1:=ma(c,5);
cross(ma(ma1,2),ma1);
或  
ma1:=ma(c,5);
cross(ref(ma1,1),ma1);

5.第1次出现条件A 选股
方法:先找出条件A,
     再利用cross(A,0.5);

例如:
{求改成第1次出现图标1选股}
ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWicon(ma1>ma2,ma1,1);
[解1]
ma1:=ma(c,5);
ma2:=ma(c,10);
A:=ma1>ma2;
cross(A,0.5);
[解2--直接将条件A写入]
ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma1>ma2,0.5);

6.线变色选股   如:黄线变红色选股 (指标线为黄线,再利用函数变红色线)
方法:先依不同软件,找出条件A,
     再用cross(A,0.5);

(1)飞狐
条件在PARTLINE(条件A, ),colorred;括号内的第1个即为条件,将该条件复制出来并加上分号即可
例如:
{求黄线变红色选股  飞狐}
ma1:ma(c,5),coloryellow;
PARTLINE(ma1>REF(ma1,1),ma1),colorred;
[解]
ma1:=ma(c,5);
A:=ma1>REF(ma1,1);
cross(A,0.5);

(2)大智慧L2.分析家
条件在PARTLINE(  ,条件A,rgb(255,0,0),  , ...);
括号内为rgb(255,0,0)的前1个即为条件,将该条件复制出来并加上分号即可
例如:
{求黄线变红色选股  大智慧L2.分析家}
ma1:=ma(c,5);
PARTLINE(ma1,ma1>REF(ma1,1),rgb(255,0,0),1,rgb(255,255,0));
[解]
ma1:=ma(c,5);
A:=ma1>REF(ma1,1);
cross(A,0.5);

(3)通达信
条件在IF(条件A,   ,DRAWNULL),colorred;括号内的第1个即为条件,将该条件复制出来并加上分号即可
例如:
{求黄线变红色选股  通达信}
MA1:MA(C,5),COLORYELLOW;
IF(MA1>REF(MA1,1),MA1,DRAWNULL),COLORRED;
[解]
MA1:=MA(C,5);
A:=MA1>REF(MA1,1);
CROSS(MA1>REF(MA1,1),0.5);

7.颜色柱选股
方法:先找出公式中出现有STICKLINE函数的地方,
找到后,核对该函数后面的颜色,是否为所求颜色,
若颜色相同,则括号内的第1个即为条件A,将该条件复制出来并加上分号即可

例如:
{求红色柱选股}
STICKLINE(c>o,h,l,0.8,1),colorred;
[解]
A:c>o;

{求第1次红色柱选股}
STICKLINE(c>o,h,l,0.8,1),colorred;
[解]
A:=c>o;
cross(A,0.5);步骤三.最后将所有绘图函数及单一输出值(如 0;  k;  if(,,); )全删除,使公式只剩1个选股式输出即成,
(若有2个以上条件,条件同时成立时,可在条件间用"and"连接;
  若有2个以上条件,条件不同时成立时,可在条件间用"or"连接)
阅读全文

论坛首页	新闻财经区	通达信选股指标公式区
精华区	新股资讯区	指南针选股指标公式区
查看新帖	股票分析软件区	股指期货区
股票投资实战交流区	股票交易实战技法区	基金区
股票市场最新信息披露区	股票证券书籍区	权证区
股票黑马荐股区	股票音频、股票视频区	债券区
股票黑马数据区	股票原码选股指标公式区	休闲娱乐区
珍贵资料区	飞狐选股指标公式区	唯美贴图区
机构报告区	同花顺选股指标公式区	音乐欣赏区
机构股评、传真区	分析家选股指标公式区	站务公告区
宏观、行业、公司报告区	大智慧选股指标公式区	网站首页